1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
|
dnl# -*- sh -*-
dnl# the "configure" script is made from this by running GNU "autoconf"
dnl#
dnl# "$Id: configure.in,v 1.12 1998/11/05 16:17:39 mike Exp $"
dnl#
dnl# Configuration script for the Fast Light Tool Kit (FLTK).
dnl#
dnl# Copyright 1998 by Bill Spitzak and others.
dnl#
dnl# This library is free software; you can redistribute it and/or
dnl# modify it under the terms of the GNU Library General Public
dnl# License as published by the Free Software Foundation; either
dnl# version 2 of the License, or (at your option) any later version.
dnl#
dnl# This library is distributed in the hope that it will be useful,
dnl# but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
dnl# Library General Public License for more details.
dnl#
dnl# You should have received a copy of the GNU Library General Public
dnl# License along with this library; if not, write to the Free Software
dnl# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
dnl# USA.
dnl#
dnl# Please report all bugs and problems to "fltk-bugs@easysw.com".
dnl#
AC_INIT(src/Fl.C)
AC_PROG_RANLIB
LIBNAME="libfltk.a"
if test "$RANLIB" != ":"; then
LIBCOMMAND="ar cr"
else
LIBCOMMAND="ar crs"
fi
DEBUGFLAG="-O2"
AC_ARG_ENABLE(debug, [ --enable-debug turn on debugging [default=no]],if eval "test x$enable_debug = xyes"; then
DEBUGFLAG="-g"
fi)
AC_ARG_ENABLE(shared, [ --enable-shared turn on shared libraries [default=no]],[
if eval "test x$enable_shared = xyes"; then
RANLIB=":"
case `uname` in
SunOS* | UNIX_S*)
LIBNAME="libfltk.so.1"
LIBCOMMAND="\$(CXX) -G $DEBUGFLAG -o"
;;
HP-UX*)
LIBNAME="libfltk.sl.1"
LIBCOMMAND="ld -b -z +h libfltk.sl.1 $DEBUGFLAGS -o"
;;
OSF1* | IRIX*)
LIBNAME="libfltk.so.1"
LIBCOMMAND="\$(CXX) -shared $DEBUGFLAG -o"
;;
*)
echo "Warning: shared libraries may not be supported. Trying -shared"
echo " option to compiler."
LIBNAME="libfltk.so.1"
LIBCOMMAND="\$(CXX) -shared $DEBUGFLAG -o"
;;
esac
fi])
CFLAGS="$DEBUGFLAG $CFLAGS"
CXXFLAGS="$DEBUGFLAG $CXXFLAGS"
AC_PROG_CC
AC_PROG_CXX
dnl# AC_PROG_INSTALL
AC_C_BIGENDIAN
AC_CHECK_SIZEOF(short, 2)
AC_CHECK_SIZEOF(int, 4)
AC_CHECK_SIZEOF(long, 4)
if test $ac_cv_sizeof_short -eq 2; then
AC_DEFINE(U16,unsigned short)
fi
if test $ac_cv_sizeof_int -eq 4; then
AC_DEFINE(U32,unsigned)
else
if test $ac_cv_sizeof_long -eq 4; then
AC_DEFINE(U32,unsigned long)
fi
fi
if test $ac_cv_sizeof_int -eq 8; then
AC_DEFINE(U64,unsigned)
else
if test $ac_cv_sizeof_long -eq 8; then
AC_DEFINE(U64,unsigned long)
fi
fi
AC_HEADER_DIRENT
AC_CHECK_FUNCS(scandir)
AC_CHECK_FUNCS(vsnprintf)
AC_CHECK_FUNCS(snprintf)
AC_CHECK_FUNCS(vsprintf)
AC_PATH_XTRA
echo "Ignoring libraries \"$X_PRE_LIBS\" requested by configure."
dnl# LIBS="$LIBS$X_LIBS$X_PRE_LIBS"
LIBS="$LIBS$X_LIBS"
CFLAGS="$CFLAGS $X_CFLAGS"
CPPFLAGS="$CPPFLAGS $X_CFLAGS"
dnl# My test to see if OpenGL is on this machine:
GLLIB=
AC_CHECK_LIB(GL, glXMakeCurrent, AC_DEFINE(HAVE_GL) GLLIB=" -lGLU -lGL", \
AC_CHECK_LIB(MesaGL,glXMakeCurrent, AC_DEFINE(HAVE_GL) GLLIB=" -lMesaGLU -lMesaGL",,\
-lX11 -lXext $X_EXTRA_LIBS -lm), \
-lX11 -lXext $X_EXTRA_LIBS -lm)
AC_SUBST(GLLIB)
AC_CHECK_HEADER(X11/extensions/Xdbe.h, AC_DEFINE(HAVE_XDBE))
AC_CACHE_CHECK("for X overlay visuals", ac_cv_have_overlay,
if xprop -root 2>/dev/null | grep -c "SERVER_OVERLAY_VISUALS" >/dev/null; then
ac_cv_have_overlay=yes
else
ac_cv_have_overlay=no
fi)
if test "$ac_cv_have_overlay" = yes; then
AC_DEFINE(HAVE_OVERLAY)
fi
MAKEDEPEND="\$(CXX) -M"
dnl# add warnings to compiler switches:
dnl# do this last so messing with switches does not break tests
if test -n "$GXX"; then
CFLAGS="-Wall $CFLAGS"
CXXFLAGS="-Wall -Wno-return-type $CXXFLAGS"
else
if test "`(uname) 2>/dev/null`" = IRIX; then
if expr "`(uname -r)`" \>= 6.2; then
dnl# Uncomment these if you don't have IDO 7.2 or higher
dnl# CXX="CC -n32"
dnl# CC="cc -n32"
dnl# LD="ld -n32"
MAKEDEPEND="CC -M"
# -woff 3322 is necessary due to errors in Xlib headers on IRIX
CFLAGS="-fullwarn $CFLAGS"
CXXFLAGS="-fullwarn -woff 1685 -woff 3322 $CXXFLAGS"
MAKEDEPEND="CC -M"
else
CXXFLAGS="+w +pp $CXXFLAGS"
fi
fi
fi
AC_SUBST(LIBNAME)
AC_SUBST(LIBCOMMAND)
AC_SUBST(MAKEDEPEND)
AC_CONFIG_HEADER(config.h:configh.in)
AC_OUTPUT(makeinclude)
dnl#
dnl# End of "$Id: configure.in,v 1.12 1998/11/05 16:17:39 mike Exp $".
dnl#
|
